/*********************************************************************
FILENAME:  MAKEDATA.SAS
SUBJECT HEADING:  DATA
INITIALS:  BML
DATE:  30 JUL 96
PROGRAM:  SAS
VERSION:  6.11 TS040
PLATFORM:  WINDOWS
TITLE:  CREATING SAS DATASETS FROM SAS TRANSPORT FILES

DESCRIPTION:  SAS DATASETS ARE DESIGNED TO WORK ON ONE PLATFORM (E.G.,
UNIX, MAC, WINDOWS) ONLY.  TO MOVE A SAS DATASET FROM ONE PLATFORM TO
ANOTHER, YOU NEED TO CONVERT THE SAS DATASET INTO A SAS TRANSPORT FILE.
THEN YOU CAN MOVE THE TRANSPORT FILE TO THE NEW PLATFORM (ALWAYS REMEMBER
TO FTP IT IN BINARY MODE).  FINALLY, YOU CHANGE THE SAS TRANSPORT FILE
BACK INTO A SAS DATASET.  THIS NEW SAS DATASET WILL BE IN THE PROPER
FORMAT FOR THE NEW PLATFORM.  THE EXAMPLE BELOW SHOWS HOW TO CONVERT A 
SAS TRANSPORT FILE INTO A SAS DATASET.

**********************************************************************/

/*

FIRST, WE CREATE A SAS DATASET TO USE AS AN EXAMPLE...

*/


options linesize=72;

data work.example;
  
  input var1 var2 $ var3;
  datalines;
  2345 able 423.55
  36625 baker 6262.65
  485 charlie 4.46
  ;

proc print data=work.example;
  title 'printout of example data stored in the work library';
run;

/*

THE NEXT BIT OF CODE CREATES A SAS TRANSPORT FILE NAMED TRANFILE.XPT IN 
THE C:\TEMP DIRECTORY.

*/

libname transprt xport 'c:\temp\tranfile.xpt';

proc copy in=work out=transprt;                                       
  select example;                                                        
run;                                                                  

/*

NOW WE WILL CONVERT THE SAS TRANSPORT FILE INTO A NEW SAS DATA SET IN THE 
C:\TEMP DIRECTORY.  THE NEW SAS DATASET WILL BE NAMED EXAMPLE.SD2 -- JUST 
LIKE THE ORIGINAL DATASET.

*/

libname import 'c:\temp\';

libname trans xport 'c:\temp\tranfile.xpt';                      
    
proc copy in=trans out=import;                                              
run;


proc print data=import.example;                                            
  title 'printout of the new data stored in c:\temp';           
run;