Operators on Root Data

RD1 eq RD2 : RootDtm, RootDtm -> BoolElt

Returns true if RD1 and RD2 are identical root data (ie. if they have the exactly the same roots and coroots).

IsIsomorphic( RD1, RD2 ) : RootDtm, RootDtm -> BoolElt

Returns true if RD1 and RD2 are isomorphic root data.

IsIsogenous( RD1, RD2 ) : RootDtm, RootDtm -> BoolElt

Returns true if RD1 and RD2 are isogenous root data.

Example RootDtm_IsomorphismIsogeny (H33E5)

> RD1 := RootDatum( "A3" );                  
> RD2 := RootDatum( "A3" : Isogeny := "sc" );
> RD1 eq RD2;
false
> IsIsomorphic( RD1, RD2 );
false
> IsIsogenous( RD1, RD2 );
true

> C := CartanMatrix( "B2" );
> RD1 := RootDatum( C );
> RD2 := RootDatum( Transpose( C ) );
> RD1 eq RD2;
false
> IsIsomorphic( RD1, RD2 );
true

RootSpace( RD ) : RootDtm -> .

CorootSpace( RD ) : RootDtm -> .

The space containing the (co)roots of the root datum RD, ie. X (resp. Y). This can be a vector space over a field of characteristic zero (Chapter VECTOR SPACES), or an integer lattice in the crystallographic case (Chapter LATTICES).

SimpleRoots( RD ) : RootDtm -> Mtrx

SimpleCoroots( RD ) : RootDtm -> Mtrx

The simple (co)roots of the root datum RD as the rows of a matrix.

CartanMatrix( RD ) : RootDtm -> AlgMatElt

The Cartan matrix of the root datum RD.

Rank( RD ) : RootDtm -> RngIntElt

The rank of the root datum RD, ie. the number of simple (co)roots.

Dimension( RD ) : RootDtm -> RngIntElt

The dimension of the root datum RD, ie. the dimension of the (co)root space. This will always be at least as large as the rank, with equality when RD is semisimple.

DynkinDiagram( RD ) : RootDtm ->

Print the Dynkin diagram of the root datum RD.

Example RootDtm_BasicOperations (H33E6)

> RD := RootDatum( "G2" );
> RootSpace( RD );
Standard Lattice of rank 2 and degree 2
> CorootSpace( RD );
Standard Lattice of rank 2 and degree 2
> SimpleRoots( RD );
[1 0]
[0 1]
> SimpleCoroots( RD );
[ 2 -3]
[-1  2]
> CartanMatrix( RD );
[ 2 -1]
[-3  2]
> Rank( RD ) eq Dimension( RD );
true
> DynkinDiagram(RD);

G2    1 =<= 2

FundamentalGroup( RD ) : RootDtm -> GrpAb

The fundamental group of the root datum RD (ie. the quotient Lambda/Z Phi; see Subsection Classification of Root Data) together with the projection from Lambda onto the fundamental group.

IsogenyGroup( RD ) : RootDtm -> GrpAb

The isogeny group of the root datum RD (ie. the quotient X/Z Phi; see Subsection Classification of Root Data) together with the injection into the fundamental group.

CoisogenyGroup( RD ) : RootDtm -> GrpAb

The coisogeny group the root datum RD (ie. the quotient Y/Z Phi^star; see Subsection Classification of Root Data) together with the projection from the fundamental group.

Example RootDtm_IsogenyGroups (H33E7)

> RD := RootDatum( "A5" : Isogeny := 3 );
> F := FundamentalGroup( RD );
> G := IsogenyGroup( RD );
> H := CoisogenyGroup( RD );
> #G * #H eq #F;
true

> A := BasisMatrix( Lattice( "A", 3 ) );
> RD := RootDatum( A, A );
> IsogenyGroup( RD );
Abelian Group isomorphic to Z
Defined on 1 generator (free)