/************************************************
 Commands for creating permanent
 SAS data sets

 FILENAME: saveperm.sas
**********************************************/

/*SPECIFY GENERIC OUTPUT USING OPTIONS FORMCHAR= */
options formchar="|----|+|---+=|-/\<>*";


libname sasdata2 V9 "c:\temp\sasdata2";
data sasdata2.pulse;
   infile "pulse.dat";
   input pulse1 pulse2 ran smokes sex height weight activity;
   pulsedif  = pulse2 - pulse1;
   htm       = (height * 2.54)/100;
   wtkg      = weight * .39;
   bmi       = wtkg / htm**2; 
run;

/*CREATE A PERMANENT DATA SET FROM AN EXCEL SPREADSHEET
  USING PROC IMPORT*/
libname sasdata2 V9 "c:\temp\sasdata2";
PROC IMPORT OUT= SASDATA2.PULSE 
            DATAFILE= "c:\temp\labdata\PULSE.XLS" 
            DBMS=EXCEL REPLACE;
     SHEET="pulse$"; 
     GETNAMES=YES;
     MIXED=NO;
     SCANTEXT=YES;
     USEDATE=YES;
     SCANTIME=YES;
RUN;

/*CREATE A PERMANENT SAS DATA SET AS OUTPUT FROM A
  SAS PROCEDURE (E.G., PROC REG)*/

libname sasdata2 V9 "c:\temp\sasdata2";
proc reg data=sasdata2.pulse;
  model pulse2 = pulse1 ;
  output out = sasdata2.resids p=predict r=resid rstudent=rstudent;
run;
quit;

proc univariate data=sasdata2.resids;
  var resid;
  histogram;
  qqplot / normal (mu=est sigma=est);
run;


/*HOW TO USE A PERMANENT SAS DATA SET IN LATER RUNS OF SAS*/
libname sasdata2 V9 "c:\temp\sasdata2";
proc means data=sasdata2.pulse;
run;
proc freq data=sasdata2.pulse;
   tables ran smokes;
run;

/*USE PROC DATASETS TO DELETE A PERMANENT SAS DATA SET*/
libname sasdata2 V9 "c:\temp\sasdata2";
proc datasets library=labdata;
  delete pulse;
  delete resids;
run; 
quit;